const int   daylightOffset_sec = 3600;

Once you are done, go ahead and try the sketch out.

/*F********************************************************************
*
**********************************************************************/
#include <WiFi.h>
#include "time.h"

//************************* DEFINES ************************************
#define  BAUD  9600
const char *ssid = "YOUR_SSID";
const char *password = "YOUR_PASS";

//************************* PROTOTYPES ************************************
void printLocalTime();

//************************* VARIABLES ************************************
const char *ntpServer = "pool.ntp.org";
const long  gmtOffset_sec = 3600;
const int   daylightOffset_sec = 3600;

/*F********************************************************************
*
**********************************************************************/
void 
setup()
{
	Serial.begin( BAUD );
	Serial.printf( "Connecting to %s ", ssid);
	WiFi.begin( ssid, password );                           // CONNECT TO WiFi
	while( WiFi.status() != WL_CONNECTED) 
	{
		delay( 500 );
		Serial.print( "." );
	}
	Serial.println( " CONNECTED");
	configTime( gmtOffset_sec, daylightOffset_sec, ntpServer);
	printLocalTime();                                     // INIT AND GET TIME
	WiFi.disconnect( true );       // DISCONNECT WiFi AS IT'S NO LONGER NEEDED
	WiFi.mode( WIFI_OFF );
}
/*F********************************************************************
*
**********************************************************************/
void 
loop()
{
	delay( 1000 );
	printLocalTime();
}
/*F********************************************************************
*
**********************************************************************/
void 
printLocalTime()
{
	struct tm timeinfo;
	if( !getLocalTime( &timeinfo ) )
	{
		Serial.println( "Failed to obtain time");
		return;
	}
	Serial.println( &timeinfo, "%A, %B %d %Y %H:%M:%S" );
}

After uploading the sketch, press the EN button on your ESP32, and you should 
get the date and time every second as shown below.






Code Explanation

Let’s take a quick look at the code to see how it works. First, we include the 
libraries needed for this project.


 WiFi.h  library provides ESP32 specific WiFi methods we 
are calling to connect to network.
 time.h  is the ESP32 native time library which does 
graceful NTP server synchronization.


#include <WiFi.h>
#include "time.h"

Next, we set up a few constants like SSID, WiFi password, UTC Offset & 
Daylight offset that you are already aware of.

const char* ssid       = "YOUR_SSID";
const char* password   = "YOUR_PASS";

const long  gmtOffset_sec = 3600;
const int   daylightOffset_sec = 3600;

Along with that we need to specify the address of the NTP Server we wish to use.
pool.ntp.org  is an open NTP project great for things like this.

const char *ntpServer = "pool.ntp.org";

The pool.ntp.org automatically picks time servers which are geographically close
for you. But if you want to choose explicitly, use one of the sub-zones 
of pool.ntp.org.



Area
HostName


Worldwide
pool.ntp.org


Asia
asia.pool.ntp.org


Europe
europe.pool.ntp.org


North America
north-america.pool.ntp.org


Oceania
oceania.pool.ntp.org


South America
south-america.pool.ntp.org


In setup section, we first initialize serial communication with PC and join the 
WiFi network using WiFi.begin()  function.



Serial.begin( BAUD );                     // BAUD DEFINED IN #defines, ABOVE
Serial.printf( "Connecting to %s ", ssid );               // CONNECT TO WiFi
WiFi.begin( ssid, password );

while( WiFi.status() != WL_CONNECTED) 
{
  delay( 500 );
  Serial.print( "." );
}
Serial.println( " CONNECTED" );


Once ESP32 is connected to the network, we initialize the NTP client using 
configTime()  function to get date and time from an NTP server.

configTime( gmtOffset_sec, daylightOffset_sec, ntpServer); //init and get time

Now we can simply call the printLocalTime() custom function whenever we want to 
print current date & time.

getLocalTime() function is used to transmit a request packet to a NTP server and
parse the received time stamp packet into to a readable format. It takes time 
structure as a parameter.

You can access the date & time information by accessing members of this time
structure.

/*F********************************************************************
*
**********************************************************************/
void 
printLocalTime()
{
	struct tm timeinfo;
	if( !getLocalTime( &timeinfo))
	{
		Serial.println( "Failed to obtain time" );
		return;
	}
	Serial.println( &timeinfo, "%A, %B %d %Y %H:%M:%S");
}

In the table below, you can see how each member of this time structure relates 
to a certain piece of information.



Symbol
Returns

%A 
 day of week

%B 
 month of year

%d 
 day of month

%Y 
 year

%H 
 hour

%M 
 minutes

%S 
 seconds